***********************************************************************
***********           PANJIT International Inc.             ***********
***********************************************************************
*JUL 12, 2019                                                         *
*                                                                     *
*This SPICE Model describes the characteristics of a typical device   *
*and does not respresent the specification. Designer should refer to  *
*the same type name data sheet for specification limits.              *
***********************************************************************
*$
.subckt GH1G-AU A K 
.param
+vc0 = 9.651e-9		 vc1 = 3.193e-11	vc2 = 4.852e-10		vc3 = 3.667e-3
+tc1 = 7.432e-2		 tc2 = 3.549e-2		tc3 = 0.892e-2		tc4 = 1.879e-2
d1 A K diode
g1 K A value = {(vc0+vc1*v(K,A))*(1.0+tc1*(temp-25)*exp(tc2*(temp-25)))+vc2*exp(vc3*v(K,A))*(1.0+tc3*(temp-25)*exp(tc4*(temp-25)))}
.model diode d
***** flag parameter *****
+level = 1
***** dc model parameter *****
+ is = 2.518e-9            n = 1.759		 rs = 2.447e-2		ikf = 1.434
+ibv = 0.1e-3		 nbv = 1		 bv = 440
***** capacitance parameter *****
+cjo = 1.498e-11	   m = 3.349e-1		 vj = 3.905e-1
+ fc = 0.5
***** temperature coefficient *****
+tnom = 25		  eg = 1.11		xti = 3
+trs1 = 3.210e-3 	trs2 = 0.251e-6
+tikf = 9.511e-3
.ends GH1G-AU
*$
